1234567891011121314151617181920212223242526272829303132333435363738394041424344 |
- dnl Distributed under the OSI-approved BSD 3-Clause License. See accompanying
- dnl file Copyright.txt or https://cmake.org/licensing for details.
- AC_DEFUN([CMAKE_FIND_BINARY],
- [AC_ARG_VAR([CMAKE_BINARY], [path to the cmake binary])dnl
- if test "x$ac_cv_env_CMAKE_BINARY_set" != "xset"; then
- AC_PATH_TOOL([CMAKE_BINARY], [cmake])dnl
- fi
- ])dnl
- AC_DEFUN([CMAKE_FIND_PACKAGE], [
- AC_REQUIRE([CMAKE_FIND_BINARY])dnl
- AC_ARG_VAR([$1][_][$2][FLAGS], [$2 compiler flags for $1. This overrides the cmake output])dnl
- AC_ARG_VAR([$1][_LIBS], [linker flags for $1. This overrides the cmake output])dnl
- failed=false
- AC_MSG_CHECKING([for $1])
- if test -z "${$1[]_$2[]FLAGS}"; then
- $1[]_$2[]FLAGS=`$CMAKE_BINARY --find-package "-DNAME=$1" "-DCOMPILER_ID=m4_default([$3], [GNU])" "-DLANGUAGE=$2" -DMODE=COMPILE $4` || failed=true
- fi
- if test -z "${$1[]_LIBS}"; then
- $1[]_LIBS=`$CMAKE_BINARY --find-package "-DNAME=$1" "-DCOMPILER_ID=m4_default([$3], [GNU])" "-DLANGUAGE=$2" -DMODE=LINK $4` || failed=true
- fi
- if $failed; then
- unset $1[]_$2[]FLAGS
- unset $1[]_LIBS
- AC_MSG_RESULT([no])
- $6
- else
- AC_MSG_RESULT([yes])
- $5
- fi[]dnl
- ])
|